enigma2.bb

   1 DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
   2 MAINTAINER = "OpenPLi team <info@openpli.org>"
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://LICENSE;md5=751419260aa954499f7abaabaa882bbe"
   5
   6 inherit gitpkgv externalsrc
   7
   8 S = "${FILE_DIRNAME}"
   9 WORKDIR = "${S}/build"
  10
  11 PV = "2.7+git"
  12 PKGV = "2.7+git${GITPKGV}"
  13 PR = "r26"
  14
  15 FILES_${PN} += "${datadir}/keymaps"
  16 FILES_${PN}-meta = "${datadir}/meta"
  17 PACKAGES =+ "${PN}-src"
  18 PACKAGES += "${PN}-meta"
  19 PACKAGE_ARCH = "${MACHINE_ARCH}"
  20
  21 inherit autotools pkgconfig pythonnative
  22
  23 ACLOCALDIR = "${B}/aclocal-copy"
  24 e2_copy_aclocal () {
  25         rm -rf ${ACLOCALDIR}/
  26         mkdir -p ${ACLOCALDIR}/
  27         if [ -d ${STAGING_DATADIR_NATIVE}/aclocal ]; then
  28                 cp-noerror ${STAGING_DATADIR_NATIVE}/aclocal/ ${ACLOCALDIR}/
  29         fi
  30         if [ -d ${STAGING_DATADIR}/aclocal -a "${STAGING_DATADIR_NATIVE}/aclocal" != "${STAGING_DATADIR}/aclocal" ]; then
  31                 cp-noerror ${STAGING_DATADIR}/aclocal/ ${ACLOCALDIR}/
  32         fi
  33 }
  34
  35 EXTRACONFFUNCS += "e2_copy_aclocal"
  36
  37 bindir = "/usr/bin"
  38 sbindir = "/usr/sbin"
  39
  40 EXTRA_OECONF = "\
  41         --enable-maintainer-mode --with-target=native --with-libsdl=no --with-boxtype=${MACHINE} \
  42         --enable-dependency-tracking \
  43         ${@base_contains("MACHINE_FEATURES", "textlcd", "--with-textlcd" , "", d)} \
  44         ${@base_contains("MACHINE_FEATURES", "colorlcd", "--with-colorlcd" , "", d)} \
  45         BUILD_SYS=${BUILD_SYS} \
  46         HOST_SYS=${HOST_SYS} \
  47         STAGING_INCDIR=${STAGING_INCDIR} \
  48         STAGING_LIBDIR=${STAGING_LIBDIR} \
  49         "
  50
  51 do_install_append() {
  52         install -d ${D}/usr/share/keymaps
  53 }
  54
  55 python populate_packages_prepend () {
  56     enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
  57     do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True, extra_depends="enigma2")
  58 }