enigma2.bb: update srctree recipe to latest oe version
[openblackhole/openblackhole-enigma2.git] / enigma2.bb
1 DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
2 MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
3 DEMUXTOOL = "${@["replex","projectx"][bb.data.getVar("TARGET_FPU",d,1) == 'hard']}"
4 DEPENDS = "jpeg libungif libmad libpng libsigc++-1.2 gettext-native \
5         dreambox-dvbincludes freetype libdvbsi++ python python-twisted swig-native  \
6         dvd+rw-tools dvdauthor mjpegtools cdrkit python-imaging ${DEMUXTOOL} \
7         libfribidi libxmlccwrap libdreamdvd libdvdcss tuxtxt-enigma2 ethtool \
8         gstreamer gst-plugins-bad gst-plugins-good gst-plugins-ugly \
9         python-wifi"
10 RDEPENDS_${PN} = "python-codecs python-core python-lang python-re python-threading \
11         python-xml python-fcntl gst-plugin-decodebin gst-plugin-decodebin2 python-stringold \
12         python-pickle gst-plugin-app \
13         gst-plugin-id3demux gst-plugin-mad gst-plugin-ogg gst-plugin-playbin \
14         gst-plugin-typefindfunctions gst-plugin-audioconvert gst-plugin-audioresample \
15         gst-plugin-wavparse python-netclient gst-plugin-mpegstream gst-plugin-selector \
16         gst-plugin-flac gst-plugin-mpegdemux gst-plugin-dvdsub \
17         gst-plugin-souphttpsrc gst-plugin-mpegaudioparse gst-plugin-subparse \
18         gst-plugin-apetag gst-plugin-icydemux gst-plugin-autodetect gst-plugin-audioparsersbad \
19         python-twisted-core python-elementtree \
20         enigma2-fonts \
21         glibc-gconv-iso8859-15 ethtool"
22
23 RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "blindscan", "virtual/blindscanutils" , "", d)}"
24
25 # Magic is the default skin, so we should depend on it.
26 DEPENDS += "enigma2-plugin-skins-magic"
27 RDEPENDS_${PN} += "enigma2-plugin-skins-magic"
28
29 # We depend on the font which we use for TXT subtitles (defined in skin_subtitles.xml)
30 DEPENDS += "font-valis-enigma"
31 RDEPENDS_${PN} += "font-valis-enigma"
32
33 RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "alsa", "gst-plugin-alsa alsa-conf", "", d)}"
34
35 # proper hdtv hardware should be able to playback these codecs (hmm, what about DVD/CD?)
36 # and rtsp support is not expected to be useful without h264 decoder
37 RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "hdtv", "\
38         gst-plugin-avi gst-plugin-matroska gst-plugin-qtdemux \
39         gst-plugin-udp gst-plugin-rtsp gst-plugin-rtp gst-plugin-rtpmanager \
40         gst-plugin-cdxaparse gst-plugin-cdio gst-plugin-vcdsrc", "", d)}"
41
42 # pick the vorbis decoder based on FPU capability
43 RDEPENDS_${PN} += "${@["gst-plugin-ivorbisdec","gst-plugin-vorbis"][bb.data.getVar("TARGET_FPU",d,1) == 'hard']}"
44
45 RDEPENDS_enigma2_append_dm7020 = " gst-plugin-ossaudio"
46
47 # FPU hardware should be able to downmix DTS
48 RRECOMMENDS_${PN} = "${@["","gst-plugin-dtsdec"][bb.data.getVar("TARGET_FPU",d,1) == 'hard']}"
49
50 # 'forward depends' - no two providers can have the same PACKAGES_DYNAMIC, however both
51 # enigma2 and enigma2-plugins produce enigma2-plugin-*.
52 #DEPENDS += "enigma2-plugins"
53 #PACKAGES_DYNAMIC = "enigma2-plugin-*"
54
55 DESCRIPTION_append_enigma2-plugin-extensions-cutlisteditor = "enables you to cut your movies."
56 RDEPENDS_enigma2-plugin-extensions-cutlisteditor = "aio-grab"
57 DESCRIPTION_append_enigma2-plugin-extensions-graphmultiepg = "shows a graphical timeline EPG."
58 DESCRIPTION_append_enigma2-plugin-extensions-pictureplayer = "displays photos on the TV."
59 DESCRIPTION_append_enigma2-plugin-systemplugins-frontprocessorupdate = "keeps your frontprocessor up to date."
60 DESCRIPTION_append_enigma2-plugin-systemplugins-positionersetup = "helps you installing a motorized dish."
61 DESCRIPTION_append_enigma2-plugin-systemplugins-satelliteequipmentcontrol = "allows you to fine-tune DiSEqC-settings."
62 DESCRIPTION_append_enigma2-plugin-systemplugins-satfinder = "helps you to align your dish."
63 DESCRIPTION_append_enigma2-plugin-systemplugins-skinselector = "shows a menu with selectable skins."
64 DESCRIPTION_append_enigma2-plugin-systemplugins-videomode = "selects advanced video modes"
65 RDEPENDS_enigma2-plugin-extensions-dvdplayer = "libdreamdvd"
66 RRECOMMENDS_enigma2-plugin-extensions-dvdplayer = "libdvdcss"
67 RDEPENDS_enigma2-plugin-systemplugins-nfiflash = "python-twisted-web"
68 RDEPENDS_enigma2-plugin-systemplugins-softwaremanager = "python-twisted-web"
69 DESCRIPTION_append_enigma2-plugin-systemplugins-crashlogautosubmit = "automatically send crashlogs to Dream Multimedia"
70 RDEPENDS_enigma2-plugin-systemplugins-crashlogautosubmit = "python-twisted-mail python-twisted-names python-compression python-mime python-email"
71 DESCRIPTION_append_enigma2-plugin-systemplugins-cleanupwizard = "informs you on low internal memory on system startup."
72 DESCRIPTION_append_enigma2-plugin-extensions-modem = "opens a menu to connect to internet via builtin modem."
73 RDEPENDS_enigma2-plugin-extensions-modem = "dreambox-modem-ppp-scripts"
74 DESCRIPTION_append_enigma2-plugin-systemplugins-wirelesslan = "helps you configuring your wireless lan"
75 RDEPENDS_enigma2-plugin-systemplugins-wirelesslan = "wpa-supplicant wireless-tools python-wifi"
76 DESCRIPTION_append_enigma2-plugin-systemplugins-networkwizard = "provides easy step by step network configuration"
77 RDEPENDS_enigma2-plugin-extensions-dvdburn = "dvd+rw-tools dvdauthor mjpegtools cdrkit python-imaging ${DEMUXTOOL}"
78
79 inherit gitpkgv srctree
80
81 PV = "2.7+git"
82 PKGV = "2.7+git${GITPKGV}"
83 PR = "r26"
84
85 FILES_${PN} += "${datadir}/keymaps"
86 FILES_${PN}-meta = "${datadir}/meta"
87 PACKAGES =+ "${PN}-src"
88 PACKAGES += "${PN}-meta"
89 PACKAGE_ARCH = "${MACHINE_ARCH}"
90
91 inherit autotools pkgconfig
92
93 # fonts: Rarely changed, but updated everytime. Put in separate package,
94 # so the dm7025 can keep them in squashfs. Also saves bandwidth...
95 PACKAGES =+ "enigma2-fonts"
96 PV_enigma2-fonts = "2010.11.14"
97 PR_enigma2-fonts = "r0"
98 PKGV_enigma2-fonts = "${PV_enigma2-fonts}"
99 FILES_enigma2-fonts = "${datadir}/fonts"
100
101 bindir = "/usr/bin"
102 sbindir = "/usr/sbin"
103
104 EXTRA_OECONF = "\
105         --enable-maintainer-mode --with-target=native --with-libsdl=no --with-boxtype=${MACHINE} \
106         ${@base_contains("MACHINE_FEATURES", "textlcd", "--with-textlcd" , "", d)} \
107         ${@base_contains("MACHINE_FEATURES", "colorlcd", "--with-colorlcd" , "", d)} \
108         BUILD_SYS=${BUILD_SYS} \
109         HOST_SYS=${HOST_SYS} \
110         STAGING_INCDIR=${STAGING_INCDIR} \
111         STAGING_LIBDIR=${STAGING_LIBDIR} \
112         "
113
114 do_install_append() {
115         install -d ${D}/usr/share/keymaps
116 }
117
118 python populate_packages_prepend () {
119         enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
120         do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True, extra_depends="enigma2")
121 }