add in-place bitbake recipe
authorpieterg <pieterg@users.sourceforge.net>
Fri, 10 Dec 2010 00:11:00 +0000 (01:11 +0100)
committerpieterg <pieterg@users.sourceforge.net>
Fri, 10 Dec 2010 00:11:00 +0000 (01:11 +0100)
to produce debug builds directly from the repository

enigma2.bb [new file with mode: 0644]

diff --git a/enigma2.bb b/enigma2.bb
new file mode 100644 (file)
index 0000000..2fe52e8
--- /dev/null
@@ -0,0 +1,103 @@
+DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
+MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
+DEPENDS = "jpeg libungif libmad libpng libsigc++-1.2 gettext-native \
+       dreambox-dvbincludes freetype libdvbsi++ python python-twisted swig-native  \
+       dvd+rw-tools dvdauthor mjpegtools cdrkit python-imaging replex \
+       libfribidi libxmlccwrap libdreamdvd libdvdcss tuxtxt-enigma2 ethtool \
+       gstreamer gst-plugins-bad gst-plugins-good gst-plugins-ugly"
+RDEPENDS_${PN} = "python-codecs python-core python-lang python-re python-threading \
+       python-xml python-fcntl gst-plugin-decodebin gst-plugin-decodebin2 python-stringold \
+       python-pickle gst-plugin-app \
+       gst-plugin-id3demux gst-plugin-mad gst-plugin-ogg gst-plugin-playbin \
+       gst-plugin-typefindfunctions gst-plugin-audioconvert gst-plugin-audioresample \
+       gst-plugin-wavparse python-netclient gst-plugin-mpegstream gst-plugin-selector \
+       gst-plugin-flac gst-plugin-mpegdemux \
+       gst-plugin-neonhttpsrc gst-plugin-mpegaudioparse gst-plugin-subparse \
+       gst-plugin-apetag gst-plugin-icydemux gst-plugin-autodetect \
+       python-twisted-core python-elementtree \
+       enigma2-fonts \
+       glibc-gconv-iso8859-15 ethtool"
+
+RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "blindscan", "virtual/blindscanutils" , "", d)}"
+
+# Magic is the default skin, so we should depend on it.
+DEPENDS += "enigma2-plugin-skins-magic"
+RDEPENDS_${PN} += "enigma2-plugin-skins-magic"
+
+# We depend on the font which we use for TXT subtitles (defined in skin_subtitles.xml)
+DEPENDS += "font-valis-enigma"
+RDEPENDS_${PN} += "font-valis-enigma"
+
+RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "alsa", "gst-plugin-alsa alsa-conf", "", d)}"
+
+# proper hdtv hardware should be able to playback these codecs
+RDEPENDS_${PN} += "${@base_contains("MACHINE_FEATURES", "hdtv", "gst-plugin-avi gst-plugin-matroska \
+                                                                               gst-plugin-qtdemux gst-plugin-cdxaparse gst-plugin-cdio gst-plugin-vcdsrc gst-plugin-vorbis", "", d)}"
+
+RDEPENDS_enigma2_append_dm7020 = " gst-plugin-ossaudio gst-plugin-ivorbisdec"
+RDEPENDS_enigma2_append_dm7025 = " gst-plugin-ivorbisdec"
+RDEPENDS_enigma2_append_dm800 = " gst-plugin-ivorbisdec"
+
+# FPU hardware should be able to downmix DTS
+RRECOMMENDS_${PN} = "${@["","gst-plugin-dtsdec"][bb.data.getVar("TARGET_FPU",d,1) == 'hard']}"
+
+# 'forward depends' - no two providers can have the same PACKAGES_DYNAMIC, however both
+# enigma2 and enigma2-plugins produce enigma2-plugin-*.
+#DEPENDS += "enigma2-plugins"
+#PACKAGES_DYNAMIC = "enigma2-plugin-*"
+
+DESCRIPTION_append_enigma2-plugin-extensions-cutlisteditor = "enables you to cut your movies."
+RDEPENDS_enigma2-plugin-extensions-cutlisteditor = "aio-grab"
+DESCRIPTION_append_enigma2-plugin-extensions-graphmultiepg = "shows a graphical timeline EPG."
+DESCRIPTION_append_enigma2-plugin-extensions-pictureplayer = "displays photos on the TV."
+DESCRIPTION_append_enigma2-plugin-systemplugins-frontprocessorupdate = "keeps your frontprocessor up to date."
+DESCRIPTION_append_enigma2-plugin-systemplugins-positionersetup = "helps you installing a motorized dish."
+DESCRIPTION_append_enigma2-plugin-systemplugins-satelliteequipmentcontrol = "allows you to fine-tune DiSEqC-settings."
+DESCRIPTION_append_enigma2-plugin-systemplugins-satfinder = "helps you to align your dish."
+DESCRIPTION_append_enigma2-plugin-systemplugins-skinselector = "shows a menu with selectable skins."
+DESCRIPTION_append_enigma2-plugin-systemplugins-videomode = "selects advanced video modes"
+RDEPENDS_enigma2-plugin-extensions-dvdplayer = "libdreamdvd"
+RRECOMMENDS_enigma2-plugin-extensions-dvdplayer = "libdvdcss"
+RDEPENDS_enigma2-plugin-systemplugins-nfiflash = "python-twisted-web"
+RDEPENDS_enigma2-plugin-systemplugins-softwaremanager = "python-twisted-web"
+DESCRIPTION_append_enigma2-plugin-systemplugins-crashlogautosubmit = "automatically send crashlogs to Dream Multimedia"
+RDEPENDS_enigma2-plugin-systemplugins-crashlogautosubmit = "python-twisted-mail python-twisted-names python-compression python-mime python-email"
+DESCRIPTION_append_enigma2-plugin-systemplugins-cleanupwizard = "informs you on low internal memory on system startup."
+DESCRIPTION_append_enigma2-plugin-extensions-modem = "opens a menu to connect to internet via builtin modem."
+RDEPENDS_enigma2-plugin-extensions-modem = "dreambox-modem-ppp-scripts"
+DESCRIPTION_append_enigma2-plugin-systemplugins-wirelesslan = "helps you configuring your wireless lan"
+RDEPENDS_enigma2-plugin-systemplugins-wirelesslan = "wpa-supplicant wireless-tools python-wifi"
+DESCRIPTION_append_enigma2-plugin-systemplugins-networkwizard = "provides easy step by step network configuration"
+RDEPENDS_enigma2-plugin-extensions-dvdburn = "dvd+rw-tools dvdauthor mjpegtools cdrkit python-imaging replex"
+
+inherit gitpkgv srctree
+
+PN = "enigma2-debug"
+PV = "2.7+git"
+PKGV = "2.7+git${GITPKGV}"
+PR = "r24"
+
+FILES_${PN} += "${datadir}/keymaps"
+FILES_${PN}-meta = "${datadir}/meta"
+PACKAGES += "${PN}-meta"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit autotools pkgconfig
+
+bindir = "/usr/bin"
+sbindir = "/usr/sbin"
+
+EXTRA_OECONF = "--enable-maintainer-mode --with-target=native --with-libsdl=no --with-boxtype=${MACHINE}"
+
+EXTRA_OECONF += "${@base_contains("MACHINE_FEATURES", "textlcd", "--with-textlcd" , "", d)}"
+EXTRA_OECONF += "${@base_contains("MACHINE_FEATURES", "colorlcd", "--with-colorlcd" , "", d)}"
+
+do_install_append() {
+       install -d ${D}/usr/share/keymaps
+}
+
+python populate_packages_prepend () {
+       enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
+
+       do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True, extra_depends="enigma2")
+}